按下shift键时速度为5

Question

我有以下代码可以让我的玩家移动：

class Player {

  PVector direction;
  PVector location;
  float rotation;
  int speed;


  Player() {
    location = new PVector(width/2, height/2);
    speed =2;
  }

  void visualPlayer() {
    direction = new PVector(mouseX, mouseY);
    rotation = atan2(direction.y - location.y, direction.x - location.x)/ PI * 180;
    if (keyPressed) {
      if ((key == 'w' && dist(location.x, location.y, direction.x, direction.y)>5) || (key == 'w' && key == SHIFT && dist(location.x, location.y, direction.x, direction.y)>5)) {
        speed = 2;
        location.x = location.x + cos(rotation/180*PI)*speed;
        location.y = location.y + sin(rotation/180*PI)*speed;

        if (key == SHIFT) {
          speed = 5;
        }
      }
    } else {
      location.x = location.x;
      location.y = location.y;
    }

    println(speed);
    ellipse(location.x, location.y, 10, 10);
  }
}

当我按下 w 键时，玩家会朝鼠标的方向移动。但是如果我按下 shift 键，我想让玩家移动得更快。但是现在当我按下 shift 键时，我的播放器停止移动……为什么会这样？？欢迎任何帮助我解决此问题的建议:)

Answer 1

这两个if 语句永远不会两者都为真：

if ((key == 'w' ) {
    if (key == SHIFT) {

在调用draw() 函数期间，key 变量只有一个值。

事实上，key 变量永远不会保存SHIFT 的值。相反，您需要使用keyCode 变量。

由于您尝试检测多个按键，您需要按照我在your other question 中告诉您的操作：您需要使用一组boolean 值来跟踪按下了哪些键，然后在您的 draw() 函数中使用它们。

这里有一个小例子，可以准确地说明我在说什么：

boolean wPressed = false;
boolean shiftPressed = false;

void draw() {
  background(0);

  if (wPressed && shiftPressed) {
    background(255);
  }
}

void keyPressed(){
  if(key == 'w' || key == 'W'){
    wPressed = true;
  }
  if(keyCode == SHIFT){
    shiftPressed = true;
  }
}

void keyReleased(){
  if(key == 'w' || key == 'W'){
    wPressed = false;
  }
  if(keyCode == SHIFT){
    shiftPressed = false;
  }
}

更多信息在the reference 或this tutorial 中，了解处理中的用户输入。