在保留调色板的同时使用 Gnuplot 矩阵中特定值的透明度？

Question

这是一个有趣的问题：

我有一个双精度二进制数据的二维“矩阵”，我想使用 Gnuplot 进行绘图。这很容易做到，如下所示：

plot "foo.dat" binary array=384x384 format='%double' with image

诀窍在于数据的某些“区域”具有特殊值，例如 1234567890.0。我希望这些元素完全透明，而所有其他矩阵元素完全不透明。有没有办法根据数据本身设置透明度通道？

我查看了 Gnuplot 文档 (link) 的相关部分，我认为我需要使用 with rgbalpha 样式，但我不确定它如何应用或如何正确映射透明度。

我也查看了这些示例 (link)，但我不确定如何应用它。

我想知道这是否可以在单行中完成（如上），或者是否需要几行（如在二进制矩阵顶部绘制轮廓时）。

提前致谢！

更新

我想我会给后代举一些例子。在所有示例中，我使用以下序言：

set title "Basic Plot"   # Or as appropriate
set size square
set palette @MATLAB   # see <http://www.gnuplotting.org/matlab-colorbar-with-gnuplot/>
set cbrange [-100000:100000]    # This cbrange fits my data well enough
                                # I would LOVE an automated way to do this!
val = 1234567890.0      # For missing data

我的基本命令产生以下内容：

plot "foo.dat" binary array=384x384 format='%double' with image

我还尝试了@Christoph 的建议：将等于val 的值替换为NaN：

plot "foo.dat" binary array=384x384 format='%double' \
    using ($1 == val ? NaN : $1) with image

我尝试使用rgbalpha 来真正控制透明度，它会产生以下结果：

plot "foo.dat" binary array=384x384 format='%double' \
    using 1:1:1:($1 == val ? 0 : 255) with rgbalpha

结论

前两种方法产生相似的结果。第一个很糟糕，因为它用错误的最大值弄乱了颜色图。第一个和第二个不足之处在于它们实际上并没有实现透明度（Gnuplot 中的“未定义”值不会自动赋予透明度）。最后一个很棒，因为它实际上控制透明度，但它是灰度的，并且没有像我想要的那样使用@MATLAB 调色板。

如果有人可以使等于val 的所有条目透明并且让颜色图正常工作，我会接受他们的回答。

***下一步要去哪里****

Gnuplot 文档提到了set datafile missing 命令 (link)。这看起来很有希望，但它似乎只适用于基于列的数据——而不是二进制文件。

我想回答我最初的问题的最佳方法是设置一组函数来模仿 rgbalpha 方法的每个“列”的给定调色板——如下所示：

red(z)   = <stuff>
green(z) = <stuff>
blue(z)  = <stuff> 
plot "foo.dat" binary array=384x384 format='%double' \
    using red($1):green($1):blue($1):($1 == val ? 0 : 255) with rgbalpha

如果这些函数以某种方式引用了当前调色板，则可以加分，因此调色板的细节不会硬编码到这三个函数中。 :-)

Answer 1

您可以通过为相应的像素赋予“NaN”值来实现：

value = 123456789.0
plot "foo.dat" binary array=384x384 format='%double' \
     using ($1 == val ? NaN : $1) with image

请注意，这取决于所选的终端。它至少适用于wxt、pdfcairo、pngcairo 和png，并且不适用于x11 和postscript。我没有测试其他终端。

这是一个独立的示例。背景颜色设置为显示像素确实是透明的而不是白色的：

set xrange [0:1]
set yrange [0:1]
set isosamples 11
set samples 11
plot '++' using 1:2:($1 == 0.5 && $2 == 0.5 ? NaN : $1) with image

4.6.5的结果是：

使用您的示例数据文件，以下脚本可以正常工作并提供很好的结果：

set terminal pngcairo size 800,800
set output 'foo.png'
set size square

f(x)=1.5-4*abs(x)
set palette model RGB
set palette functions f(gray-0.75),f(gray-0.5),f(gray-0.25)

val = 1234567890.0

set autoscale xfix
set autoscale yfix
set cbrange [-10000:10000]
plot 'foo.dat' binary array=(512,512) format='%double' using ($1 == val ? NaN : $1) with image notitle