数组按字母顺序排序？

Question

假设我有两个字符串数组，名为“arrayone”和“arraytwo” 我将如何按字母顺序（从 A 到 Z）对“arrayone”进行排序，同时仍保持与我的第二个数组的关系。

如果您想知道“arrayone”和“arraytwo”中有什么，1 有姓氏，2 有每个人的年龄。我的最终结果是将其添加到 Richedit 中。

场景示例：

Smith           25 
Appleseed       32
Gibbs           45

必须变成：

Appleseed       32
Gibbs           45
Smith           25

请不要使用字符串列表，将其保存在简单的数组和过程中。

更新：我切换到录制。

试过这段代码没有用

for i := 0 to 26 do
for j := 0 to 26 do
  if recordname.surname[j] > recordname.surname[j+1] then begin
    line := recordname.surname[j];
    line[j] := recordname.surname[j+1];
    recordname.surname[j+1] := line;
  end;

上面写着不兼容的类型：'Char' 和 'String'

Answer 1

在为您提供了有关数据结构的建议并看到了随之而来的困难之后，我想直截了当并更清楚地解释我的意思。

您的原始代码有两个基本上没有连接的数组。您可以交换一个数组中的项目，而很容易忘记为另一个数组这样做。在我看来，姓名/年龄对真的不应该分开。这导致以下类型声明。

type
  TPerson = record
    Name: string;
    Age: Integer;
  end;

现在你需要保存TPerson的数组。

type
  TPersonArray = array of TPerson;

为了执行排序，您需要能够比较两个项目并交换它们。

function Compare(const Person1, Person2: TPerson): Integer;
begin
  Result := CompareText(Person1.Name, Person2.Name);
end;

procedure Swap(var Person1, Person2: TPerson);
var
  temp: TPerson;
begin
  temp := Person1;
  Person1 := Person2;
  Person2 := temp;
end;

现在我们可以用冒泡排序将所有这些放在一起。

procedure Sort(var People: TPersonArray);
var
  i, n: Integer;
  Swapped: Boolean;
begin
  n := Length(People);
  repeat
    Swapped := False;
    for i := 1 to n-1 do begin
      if Compare(People[i-1], People[i])>0 then begin
        Swap(People[i-1], People[i]);
        Swapped := True;
      end;
    end;
    dec(n);
  until not Swapped;
end;

现在，如果您想使用更复杂的比较运算符，则只需替换 Compare。例如，如果您想按年龄对任何同名的人进行排序，那么您可以使用字典比较函数。

function Compare(const Person1, Person2: TPerson): Integer;
begin
  Result := CompareText(Person1.Name, Person2.Name);
  if Result=0 then begin
    Result := Person2.Age-Person1.Age;
  end;
end;

我已经逐条写了这个答案，这就是你应该如何处理这样一个更大的问题。尝试将其分解成更小的部分，每个部分都易于管理。

Answer 2

我们的TDynArray wrapper 只是明确处理此功能。

您可以使用自定义排序函数直接就地排序任何现有动态数组，或使用索引的整数数组。

function PersonCompare(const Person1, Person2: TPerson): Integer;
begin // sample function pasted from David's answer
  Result := CompareText(Person1.Name, Person2.Name);
  if Result=0 then 
    Result := Person2.Age-Person1.Age;
end;

type
  TPersonDynArray = array of TPerson;

function SortPersons(var Persons: TPersonDynArray);
var
  Person: TDynArray;
begin
  Person.Init(TypeInfo(TPersonDynArray),Persons);
  Person.Compare := PersonCompare;
  Person.Sort;
end;

顺便说一下，包装器的Sort方法会使用优化过的快速排序，比冒泡排序算法快很多。

这个包装器中还有更多功能，例如类似 TList 的方法，如 Add() 或 Delete()，使用外部 Count 变量（添加速度更快），序列化或使用散列快速查找。

它适用于 Delphi 5 到 XE2，并且是开源的。

Answer 3

无需创建包含两组数据点的新结构，您可以使用基于 arrayone 进行检查的比较函数对索引数组进行排序。

更具体地说，最初使用indices[i] = i 创建一个数组indices。

然后，使用比较函数对indices进行排序

i < j iff arrayone[indices[i]] < arrayone[indices[j]]

那么，读取arrayone[indices[0]], arrayone[indices[1]] ...给你排序后的列表，对应的值为arraytwo[indices[0]], arraytwo[indices[1]], ...

Answer 4

使用您选择的排序算法对第一个数组进行正常排序。任何介绍算法的教科书都会有几个。每次交换第一个数组的两个条目时，对第二个数组的相应条目进行相同的更改。