从用户输入创建一个列表，它应该在 Prolog 中合并排序

Question

所以我的程序应该询问用户要输入多少个数字，然后用户将输入要排序的数字，排序算法应该是合并排序。

main:-   
   writeln('Number of items? '),
   read(N),
   length(L, N),
   maplist(read, L),    
   mergesort(L, S). 

mergesort([L,B|R],S):-
    split([L, B|R], A1, A2),
    mergesort(A1, S1),
    mergesort(A2, S2),
    format('Sorted list: ~w~n', merge(S1, S2, S)).
    
split([],[],[]).
split([L], [L],[]).
split([L, B|R], [L|Ra], [B|Rb]) :-
    split(R, Ra, Rb).
    
merge(L, [], L).
merge([], B, B).
merge([L|Ra], [B|Rb], [L|M]) :-
    L=< B, 
    merge(Ra, [B|Rb], M).
merge([L|Ra], [L|Rb], [B|M]) :-
    L > B, 
    merge([A|Ra], Rb, M). 

这不起作用，在用户输入要排序的数字后，它总是显示 false。

Answer 1

我在您的代码中发现了两个问题。第一个是最后一条规则中的错字：您混淆了A 和B 和/或L。应该是这样的

merge([A|Ra], [L|Rb], [L|M]) :-
    L < A, 
    merge([A|Ra], Rb, M).

第二个错误是您从未说明何时结束递归拆分。我建议把

mergesort([A],[A]):-!.

在您的主要 mergesort 规则之前。爆炸（!）被称为剪切，在这种情况下可以防止进一步的回溯。这会缩短代码，因为如果您的列表包含多个元素，您不必检查“main”mergesort 规则。

---

完整代码；在SWISH工作

mergesort([A],[A]):-!.
mergesort([L,B|R],S):-
    split([L, B|R], A1, A2),
    mergesort(A1, S1),
    mergesort(A2, S2),
    merge(S1, S2, S).
    
split([],[],[]).
split([L], [L],[]).
split([L, B|R], [L|Ra], [B|Rb]) :-
    split(R, Ra, Rb).
    
merge(L, [], L).
merge([], B, B).
merge([L|Ra], [B|Rb], [L|M]) :-
    L=< B, 
    merge(Ra, [B|Rb], M).
merge([A|Ra], [L|Rb], [L|M]) :-
    L < A, 
    merge([A|Ra], Rb, M).

测试用例

?- mergesort([5,2,4,7,1,0],L).
L = [0, 1, 2, 4, 5, 7] ;
false.

工作。