VBA - 应用过滤器后删除可见行

Question

我有两个宏，它们按日期过滤工作表列，然后删除不相关的列。

但是，它有很多错误，我需要一些帮助来纠正它。

这是第二个宏应该做的：

1) 在应用过滤器后只需删除可见行，第一行（标题）除外 - 目前，它会删除包括第一行在内的所有可见行，即使我有 @987654321 @我的代码中的函数。

2) 删除所有过滤器 - 现在可以正常工作了

Sub DeleteVisibleRows()

Dim ws1 As Worksheet
Dim WorkRng As Range

Set ws1 = ActiveWorkbook.Sheets("Consolidated")

On Error Resume Next

Set WorkRng = Application.Selection

Application.ScreenUpdating = False
With ws1

WorkRng.Offset(1, 0).Rows.SpecialCells(xlCellTypeVisible).EntireRow.Delete

ws1.AutoFilterMode = False

End With

Application.ScreenUpdating = True
End Sub

Answer 1

SpecialCells 将像之前的答案一样工作。

    Sub Button1_Click()
    Dim sh As Worksheet, rng As Range, LstRw As Long

    Set sh = Sheets("Sheet1")
    With sh
        LstRw = .Cells(.Rows.Count, "A").End(xlUp).Row
        Set rng = .Range("A2:A" & LstRw).SpecialCells(xlCellTypeVisible)
        rng.EntireRow.Delete
        .AutoFilterMode = False
    End With
End Sub

Answer 2

删除过滤数据行是我在 excel 中处理表格时不时需要做的事情，但在删除重要内容时我永远不能相信宏。如果您仍想使用它，这可能对您有用：

Sub DeleteVisibleRows()
Dim ws As Worksheet
Dim lastrow As Long, i As Long

Set ws = ThisWorkbook.Worksheets("Consolidated")
With ws
    lastrow = .Cells(.Rows.Count, "B").End(xlUp).Row
    For i = lastrow To 2 Step -1 'To 2 Assuming first row contains headers
        If .Rows(i).Hidden = False Then
            .Rows(i).Delete
        End If
    Next
.ShowAllData 'remove filtered data
End With
End Sub

Answer 3

如果您使用SELECTION，则无需定义工作表。您需要的一切都与您的选择相关 - 您的选择可能不在 Consolidated 工作表上，但它始终在您选择的父对象上。

下面的代码假定您应用了过滤器 - 如果不是，则标题下方的所有内容都将被删除。

Public Sub DeleteVisibleRows()

    Dim WorkRng As Range

    Set WorkRng = Selection

    With WorkRng
        .Offset(1, 0).Resize(.Rows.Count - 1).SpecialCells(xlCellTypeVisible).EntireRow.Delete
    End With

    WorkRng.Parent.AutoFilterMode = False

End Sub  

编辑：这段代码太长了，我会删掉一些垃圾。

Public Sub DeleteVisibleRows()

    With Selection
        .Offset(1, 0).Resize(.Rows.Count - 1).SpecialCells(xlCellTypeVisible).EntireRow.Delete
        .Parent.AutoFilterMode = False
    End With

End Sub