Windows CMD Batch：在循环中连接变量 NAME

Question

在 Windows CMD 批处理循环中，我想使用动态变量：list1、list2 和 list3，其中数字 1-3 是动态的（即：list&i），但我正在努力：

setlocal enabledelayedexpansion enableextensions
SET threads=3
set i=1

for /R %%x in (*.jpg) do  ( call set LISTNAME=LIST!i! & SET LIST!i!=!LISTNAME! "%%x" & set /A i=!i!+1  & if !i! gtr %threads% (set i=1))

echo "first" %LIST1%
echo "second" %LIST2%
echo "third" %LIST3%

我挣扎的确切位置是：

SET LIST!i!=!LISTNAME! "%%x" 

例如，我希望它在哪里：

SET LIST1=!LIST1! "%%x"

但是，listname 只是转换为字符串 LIST1，而不是变量 LIST1。 我也试过没有成功：

SET LIST!i!=!LIST!i!! "%%x"

脚本的目的：将 JPG 文件名放在 3 个列表中 编辑以回答第一条评论：文件名以循环方式分布并用空格分隔。

Answer 1

假设循环分布，您可以通过模数计算轻松获得列表编号。出于演示目的，我只输出 filename.ext 而没有 drive:path。

@Echo off
setlocal enabledelayedexpansion enableextensions
Set /A "threads=3,i=0"
:: initialize List
For /L %%n in (1,1,%threads%) Do Set "List%%n="

for /R %%x in (*.jpg) do  ( 
  Set /A "n=i %% threads + 1,i+=1"
  for %%n in (!n!) do Set "List%%n=!List%%n! %%~nxx"
  rem call set "LIST!n!=%%LIST!n!%% %%~nxx"
)
echo "first " %LIST1%
echo "second" %LIST2%
echo "third " %LIST3%

样本输出

"first "  watch_dogs1.jpg watch_dogs4.jpg watch_dogs7.jpg
"second"  watch_dogs2.jpg watch_dogs5.jpg watch_dogs8.jpg
"third "  watch_dogs3.jpg watch_dogs6.jpg watch_dogs9.jpg

EDIT插入了延迟扩展的for变量类型。