GetResponse 不是 UWP 中 WebRequest 的成员

Question

我编写了一个 VB 程序来访问 Web 上的信息。 它可以工作，但是当尝试在 UWP（通用 Windows）中做同样的事情时...... 我收到以下消息： "'GetResponse' 不是 'WebRequest' 的成员"

这是我使用较少网站信息的代码。如何在通用 Windows 平台中使用此代码。

Imports System
Imports System.IO
Imports System.Net

Module Code

    Sub SendWebRequest()

        Dim MyWebRequest As WebRequest
        Dim MyWebResponse As WebResponse
        Dim SR As StreamReader
        Dim ReadString As String

        Dim MyCache As New CredentialCache()
        Dim MyCredential As NetworkCredential = MyCache.GetCredential(New Uri("http://xxxxxx.com:xxxx"), "Basic")
        If MyCredential Is Nothing Then
            MyCache.Add(New Uri("http://http://xxxxxx.com:xxxx"), "Basic", New NetworkCredential("UserName", "UsePassWord"))
        End If

        MyWebRequest = WebRequest.Create("http://http://xxxxxx.com:xxxx/xxxx")

        MyWebRequest.Credentials = myCache
        MyWebResponse = MyWebRequest.GetResponse()

        SR = New StreamReader(MyWebResponse.GetResponseStream)
        Do
            ReadString = SR.ReadLine
            If InStr(ReadString, "Listen to the pronunciation of") Then
                'Do Something
                Exit Do
            End If
        Loop Until SR.EndOfStream

        MyWebResponse.Close()
    End Sub
End Module

我使用添加 Async 和 Await 进行了更新。 . . MyWebresponse = Await MyWebRequest.GetResponseAsync() 的运行时问题 异常用户未处理：System.PlatformNotSupportedException：'属性'Credentials'不支持值'System.Net.CredentialCache'。'

Async Sub SendWebRequest()
    Dim MyWebRequest As WebRequest
    Dim MyWebResponse As WebResponse
    Dim SR As StreamReader
    Dim ReadString As String
    Dim MyCache As New CredentialCache()
    Dim MyCredential As NetworkCredential = MyCache.GetCredential(New Uri("http://xxxxxx.com:xxxx"), "Basic")
    If MyCredential Is Nothing Then
        MyCache.Add(New Uri("http://http://xxxxxx.com:xxxx"), "Basic", New NetworkCredential("UserName", "UsePassWord"))
    End If
    MyWebRequest = WebRequest.Create("http://http://xxxxxx.org:xxxx/xxxx")
    MyWebRequest.Credentials = myCache
    MyWebResponse = Await MyWebRequest.GetResponseAsync()
    SR = New StreamReader(MyWebResponse.GetResponseStream)
    Do
        ReadString = SR.ReadLine
        If InStr(ReadString, "Listen to the pronunciation of") Then
            'Do Something
            Exit Do
        End If
    Loop Until SR.EndOfStream

    MyWebResponse.Close()
End Sub

如果有人能看到我在上面做错了什么，我将不胜感激。 同时，我将按照 jmcilhinney 的建议尝试 HttpClient

Answer 1

理论上，你应该可以改变这个：

Sub SendWebRequest()

到这里

Async Sub SendWebRequest()

还有这个：

MyWebResponse = MyWebRequest.GetResponse()

到这里：

MyWebResponse = Await MyWebRequest.GetResponseAsync()

This thread 表示这可能不起作用。它确实建议使用HttpClient 作为替代方案，这意味着代码如下：

Dim client As New HttpClient
Dim response = Await client.GetAsync(New Uri("URL here"))

If response.IsSuccessStatusCode Then
    Dim data = Await response.Content.ReadAsStringAsync()

    For Each line In data.Split({vbLf, vbCrLf}, StringSplitOptions.RemoveEmptyEntries)
        'Use line here.
    Next
End If

请注意，我不能 100% 确定这些“vb”常量是否可以在 UWP 中使用，但为了简单起见，我在这里使用它们。

Answer 2

以下是我在 UWP 中需要的。发送 Web 请求并监控返回。 ...感谢 jmcilhinney 的帮助

导入 System.Net

导入 System.Net.Http

导入 System.Text

模块代码

Async Sub SendWebRequest()
    Dim client As New HttpClient

    Dim byteArray = Encoding.ASCII.GetBytes("UserName:PassWord")
    client.DefaultRequestHeaders.Authorization = New System.Net.Http.Headers.AuthenticationHeaderValue("Basic", Convert.ToBase64String(byteArray))

    Dim response = Await client.GetAsync(New Uri("http://xxxxx.xxxxxx.org:####/xxxxx"))

    If response.IsSuccessStatusCode Then
        Dim data = Await response.Content.ReadAsStringAsync()

        For Each line In data.Split({vbLf, vbCrLf}, StringSplitOptions.RemoveEmptyEntries)
            'Use line here.
        Next
    End If
End Sub

结束模块