将列匹配到一个单独的文件并将匹配项附加到文件

Question

我正在尝试使用 awk 合并在单个列上过滤的两个文件。然后我想做的是将文件 2 中的相关列附加到文件 1 中。

用虚拟例子更容易解释。

文件1

name   fruit   animal
bob    apple   dog
jim    orange  cat
gary   mango   snake
daisy  peach   mouse

文件 2：

 animal number  shape
 cat    eight   square
 dog    nine    circle
 mouse  eleven  sphere

期望的输出：

 name   fruit   animal  shape   
 bob    apple   dog     circle
 jim    orange  cat     square
 gary   mango   snake   NA
 daisy  peach   mouse   sphere

第1步：需要过滤file1中的第3列和file2中的第1列

awk -F'\t' 'NR==FNR{c[$3]++;next};c[$1] > 0' file1 file2

这给了我输出：

cat    eight   square
dog    nine    circle
mouse eleven   sphere

这对我有所帮助，但是我不能简单地从上面的输出中剪切第三列（形状）并将其附加到 file1，因为在 file2 中没有“snake”条目。我需要能够将输出的第 3 列附加到匹配成功的文件 1 中，并且不放置“NA”。必须保留 file1 中的所有行，所以我不能忽略它们。这就是我卡住的地方！

如果有任何帮助，我将不胜感激...... E

Answer 1

您能否尝试根据 GNU awk 中显示的示例进行跟踪、编写和测试。

awk '
BEGIN{
  OFS="\t"
}
FNR==NR{
  a[$1]=$NF
  next
}
{
  print $0,($3 in a?a[$3]:"NA")
}'  Input_file2   Input_file1

说明：为上面添加详细说明。

awk '                               ##Starting awk program from here.
BEGIN{                              ##Starting BEGIN section from here.
  OFS="\t"                          ##Setting TAB as output field separator here.
}
FNR==NR{                            ##Checking condition FNR==NR which will be TRUE when first Input_file file2 is being read.
  a[$1]=$NF                         ##Creating array a with index $1 and value is $NF for current line.
  next                              ##next will skip all further statements from here.
}
{
  print $0,($3 in a?a[$3]:"NA")     ##Printing current line and checking if 3rd field is present in array a then print its value OR print NA.
}'  file2  file1                    ##Mentioning Input_file names here.