在 Snakemake 中处理等效的文件扩展名

Question

基本上，我想知道在snakemake 中推荐的处理等效文件扩展名的方法是什么。例如，假设我有一个规则来计算 fasta 文件中的条目数。该规则可能看起来像....

rule count_entries:
    input:
        ["{some}.fasta"]
    output:
        ["{some}.entry_count"]
    shell:
        'grep -c ">" {input[0]} > {output[0]}'

这很好用。但是如果我希望这条规则也允许“{some}.fa”作为输入呢？

有什么干净的方法可以做到这一点吗？

编辑：

这是我对第一个建议解决方案的最佳猜测。这可能可以转换为更高阶的函数以更通用，但这是我理解的基本思想。我认为这个想法并不真正适合任何一般用例，因为它在“构建 DAG”阶段不与其他规则合作。

import os

def handle_ext(wcs):
    base = wcs["base"]
    for file_ext in [".fasta", ".fa"]:
        if(os.path.exists(base + file_ext)):
            return [base + file_ext]

rule count_entries:
    input:
        handle_ext
    output:
        ["{base}.entry_count"]
    shell:
        'grep -c ">" {input[0]} > {output[0]}'

EDIT2：这是我认为目前最好的解决方案...

count_entries_cmd = 'grep -c ">" {input} > {output}'
count_entries_output = "{some}.entry_count"

rule count_entries_fasta:
    input:
        "{some}.fasta"
    output:
        count_entries_output
    shell:
        count_entries_cmd

rule count_entries_fa:
    input:
        "{some}.fa"
    output:
        count_entries_output
    shell:
        count_entries_cmd

Answer 1

我注意到的一件事是，您试图在输入和输出部分中指定文件列表，但实际上您的规则采用单个文件并生成另一个文件。 我建议你一个简单的解决方案，为不同的扩展指定两个单独的规则：

rule count_entries_fasta:
    input:
        "{some}.fasta"
    output:
        "{some}.entry_count"
    shell:
        'grep -c ">" {input} > {output}'

rule count_entries_fa:
    input:
        "{some}.fa"
    output:
        "{some}.entry_count"
    shell:
        'grep -c ">" {input} > {output}'

除非您将具有相同 {some} 名称和不同扩展名的文件保存在同一个文件夹中（我希望您不要这样做），否则这些规则并不含糊。

Answer 2

一种可能的解决方案是只允许原始规则将 .fasta 文件作为输入，但允许将 .fa 文件重命名为该规则。例如，

rule fa_to_fasta:
    input:
        "{some}.fa"
    output:
        temp("{some}.fasta")
    shell:
        """
        cp {input} {output}
        """

显然，这样做的缺点是制作文件的临时副本。此外，如果foo.fa 和foo.fasta 都提供了（不是通过复制），那么foo.fasta 将默默地覆盖foo.fa，即使它们不同。