来自文件的 Perl 正则表达式——如何使用 $1？

Question

我有一个在字符串上运行的正则表达式列表，用于将其从一种格式格式转换为另一种格式。目前，所有这些正则表达式都存储在一个文件中。

通常，这可以正常工作。如果它将“Frog”读入$from，将“Toad”读入$to，那么“$string =~ s/$from/$to/”会根据需要将所有青蛙变成蟾蜍。

现在我想做一些更棘手的事情：给定日期“2015-04-15”，我想将其更改为“04/2015”，再次从文件中读取。如果我将“(\d\d\d\d)-(\d\d)-(\d\d)”加载到 $from 并将“$2/$1”加载到 $to，这不起作用：它替换带有文字字符串“$2/$1”的日期，输出中带有实际的美元符号。我需要做什么？

这是一个仅供家庭使用的脚本。如果可以让我的生活更简单，我很乐意使用 eval{} 或任何其他奇怪的东西。

Answer 1

要评估替换中的替换，请使用/ee 修饰符。这会将替换表达式 ($to) 作为 Perl 代码执行，并将其结果（$to 的值）传递给 eval EXPR。因此，$to 需要包含有效的 Perl 代码，这意味着您必须引用表达式以避免将其评估为除法。

my $in = '2015-04-15';
my $expected = '04/2015';

my $from = '(\d\d\d\d)-(\d\d)-(\d\d)';
my $to = '"$2/$1"';

$in =~ s/$from/$to/ee;
print $in eq $expected ? 'YES' : 'NO';

Answer 2

您可以使用以下内容：

my $from = '(\d\d\d\d)-(\d\d)-(\d\d)';
my $to = '"$2/$1"';
my $string = '2015-04-15';
$string =~ s/$from/$to/ee;

上面是下面的缩写：

my $from = '(\d\d\d\d)-(\d\d)-(\d\d)';
my $to = '"$2/$1"';
my $string = '2015-04-15';
$string =~ s/$from/ eval($to) /e;

我更喜欢第二个而不是第一个，因为它不会隐藏使用eval(EXPR) 的事实。但是，上述两个静音错误，所以以下会更好：

my $from = '(\d\d\d\d)-(\d\d)-(\d\d)';
my $to = '"$2/$1"';
my $string = '2015-04-15';
$string =~ s/$from/ my $r = eval($to); die $@ if $@; $r /e;

但正如您所见，以上所有内容都允许执行任意 Perl 代码。以下会更安全：

use String::Substitution qw( gsub_modify );

my $from = '(\d\d\d\d)-(\d\d)-(\d\d)';
my $to = '$2/$1';
my $string = '2015-04-15';
gsub_modify($string, $from, $to);