Perl 使用 $1 进行变量插值替换

Question

我正在尝试在替换字符串中使用变量插值，包括$1、$2、... 但是，我无法将 $1 扩展为替换。我最终将拥有 $pattern 和 $replacement 变量可以从配置文件中读取，但即使 手动设置它们不起作用。

在示例脚本中，您可以看到$1（应该是'DEF'）不是 在$new_name 中展开，但它在$new_name2 中（没有变量）。

在替换中添加一个“e”标志没有帮助。

我该如何解决这个问题？

马特

示例代码：

#!/usr/local/bin/perl
use strict;

my $old_name = 'ABC_DEF_GHI';

my $pattern = 'ABC_(...)_GHI';
my $replacement = 'CBA_${1}_IHG';

# using variables - doesn't work
my $new_name = $old_name;
$new_name =~ s|$pattern|$replacement|;

printf("%s --> %s\n", $old_name, $new_name);


# not using variables - does work
my $new_name2 = $old_name;
$new_name2 =~ s|ABC_(...)_GHI|CBA_${1}_IHG|;

printf("%s --> %s\n", $old_name, $new_name2);

输出：

ABC_DEF_GHI --> CBA_${1}_IHG
ABC_DEF_GHI --> CBA_DEF_IHG

Answer 1

您需要在您的代码中进行此更改：

my $replacement = '"CBA_$1_IHG"';  #note the single and double quotes
# ...
$new_name =~ s|$pattern|$replacement|ee;  #note the double "ee", double evaluation

See this SO answer了解更多信息

Answer 2

/e 将$replacement 视为 Perl 代码。 Perl 代码$replacement 只返回它包含的值。

如果你想将$replacement的内容评估为Perl代码，你需要

s/$search/ my $s = eval $replacement; die $@ if $@; $s /e

可以写成

s/$search/$replacement/ee

请注意，由于$replacement 应该包含 Perl 代码，这意味着它可以用于执行任意 Perl 代码。

更好的解决方案是意识到您正在编写自己的低于标准的模板系统，并改用现有的。 String::Interpolate 了解您当前使用的模板语法：

use String::Interpolate qw( interpolate );
s/$search/interpolate $replace/e