Perl：逐行添加2个文件

Question

我是 perl 的初学者，所以请多多包涵。

我有 2 个文件：

1
2
3

和

2
4
5
6

我想创建一个新文件，它是上述 2 个文件的总和：

输出文件：

3
6
8
6

我现在正在做的是将文件作为数组读取并逐个元素地添加它们。

要添加我正在使用的数组：

$asum[@asum] = $array1[@asum] + $array2[@asum] while defined $array1[@asum] or defined $array2[@asum];

但这给出了以下错误：

Argument "M-oM-;M-?3" isn't numeric in addition (+) at perl_ii.pl line 30.
Argument "M-oM-;M-?1" isn't numeric in addition (+) at perl_ii.pl line 30.
Use of uninitialized value in addition (+) at perl_ii.pl line 30.

我正在使用以下代码将文件作为数组读取：

use strict;
use warnings;

my @array1;
open(my $fh, "<", "file1.txt") or die "Failed to open file1\n";
while(<$fh>) { 
    chomp; 
    push @array1, $_;
} 
close $fh;

my @array2;
open(my $fh1, "<", "file2.txt") or die "Failed to open file2\n";
while(<$fh1>) {
    chomp;
    push @array2, $_;
}
close $fh1 ;

谁能告诉我如何解决这个问题，或者提供更好的方法？

Answer 1

这是另一个使用菱形文件读取运算符<> 的 Perl 解决方案。这会读入命令行上指定的文件（而不是在程序中显式打开它们）。抱歉，我找不到解释这一点的文档部分。

此程序的命令行如下所示：

perl myprogram.pl file1 file2 > outputfile

其中file1和file2是2个输入文件，outputfile是要打印相加结果的文件。

#!/usr/bin/perl
use strict;
use warnings;

my @sums;
my $i = 0;
while (my $num = <>) {
    $sums[$i++] += $num;
    $i = 0 if eof;
}

print "$_\n" for @sums;

注意：$i 在文件末尾被重置为零，（在这种情况下，在读取第一个文件之后）。实际上，在读取第二个文件后它也被重置为 0。但是，这对程序没有影响，因为在您的示例中的第二个文件之后没有要读取的文件。

Answer 2

以下解决方案使程序的内存占用与文件的大小无关。相反，现在内存占用仅取决于文件的数量：

#!/usr/bin/env perl

use strict;
use warnings;

use Carp qw( croak );
use List::Util qw( sum );
use Path::Tiny;

run(@ARGV);

sub run {
    my @readers = map make_reader($_), @_;

    while (my @obs = grep defined, map $_->(), @readers) {
        print sum(@obs), "\n";
    }

    return;
}

sub make_reader {
    my $fname = shift;
    my $fhandle = path( $fname )->openr;
    my $is_readable = 1;
    sub {
        return unless $is_readable;

        my $line = <$fhandle>;
        return $line if defined $line;

        close $fhandle
            or croak "Cannot close '$fname': $!";

        $is_readable = 0;
        return;
    }
}

Answer 3

您的脚本现在有两个不同的问题：

1. 第一个错误

   参数 "M-oM-;M-?3" 在 perl_ii.pl 行不是数字加法 (+) 30

   发生是因为您的输入文件以 Unicode 格式保存，并且第一行使用“\xFF\xFE”BOM 字节读取。 为了简单地修复它，只需将文件重新保存为 ANSI 文本。如果需要 Unicode，则从您从文件中读取的第一个字符串中删除这些字节。

2. 第二个错误

   在 perl_ii.pl 第 30 行使用未初始化的值加法 (+)。

   发生是因为您访问了第一个不存在的数组中的第 4 个元素。请记住，您选择最大输入数组长度作为索引限制。要修复它，只需为输入元素添加以下条件：

   $asum[@asum] = (@asum < @array1 ? $array1[@asum] : 0)  + (@asum < @array2 ? $array2[@asum] : 0) while defined $array1[@asum] or defined $array2[@asum];
   

Answer 4

读取你的两个文件的逻辑是一样的，我建议使用一个子程序并调用它两次：

#!/usr/bin/env perl

use strict;
use warnings;

my @array1 = read_into_array('file1.txt');
my @array2 = read_into_array('file2.txt');

sub read_into_array
{
    my $filename = shift;
    my @array;
    open(my $fh, "<", $filename) or die "Failed to open $filename: $!\n";
    while(<$fh>) { 
        chomp; 
        push @array, $_;
    } 
    close $fh;
    return @array;
}

但这只是我的观察，并不能解决您的问题。作为CodeFuller already said，您应该将文件重新保存为纯 ASCII 而不是 UTF-8。

第二个问题，使用未初始化的值加法 (+)，也可以通过在 Perl 5.10 中引入的Logical Defined Or 运算符// 来解决：

my @asum;
$asum[@asum] = ($array1[@asum] // 0) 
             + ($array2[@asum] // 0) 
             while defined $array1[@asum] or defined $array2[@asum];

不，这不是评论，而是与|| 非常相似的运算符。不同之处在于它在左侧（lhs）为undef 时触发，而|| 在lhs 为falsy 时触发（即0、'' 或@987654331 @)。因此

$array1[@asum] // 0

如果 $array1[@asum] 是 undef，则给出 0。是一样的

defined($array1[@asum]) ? $array1[@asum] : 0

Answer 5

完全不同的方法：

$ paste -d '+' file1 file2 | sed 's/^+//;s/+$//' | bc
3
6
8
6

paste 命令将文件彼此相邻打印，以+ 符号分隔：

$ paste -d '+' file1 file2
1+2
2+4
3+5
+6

sed 命令删除前导和尾随 + 符号，因为它们会绊倒 bc：

$ paste -d '+' file1 file2 | sed 's/^+//;s/+$//'
1+2
2+4
3+5
6

bc 最终计算总和。

Answer 6

这是Sinan’s approach 的更 Perlish 形式的再现：

#!/usr/bin/env perl
use 5.010; use strict; use warnings;

use autodie;
use List::Util 'sum';

my @fh = map { open my $fh, '<', $_; $fh } @ARGV;

while ( my @value = grep { defined } map { scalar readline $_ } @fh ) {
    say sum @value;
    @fh = grep { not eof $_ } @fh if @value < @fh;
}